WIP Discovery

Microsoft.HostIntegrationServer.2010.WIPDiscovery (Discovery)

Discovery for WIP

Knowledge Base article:

Element properties:

Object Discovery Details:

Member Modules:

Source Code:

<Discovery ID="Microsoft.HostIntegrationServer.2010.WIPDiscovery" Enabled="true" Target="Microsoft.HostIntegrationServer.2010.AppInt" ConfirmDelivery="false" Remotable="true" Priority="Normal">

  <Category>Discovery</Category>

  <DiscoveryTypes>

    <DiscoveryClass TypeID="Microsoft.HostIntegrationServer.2010.WIP">

      <Property TypeID="System!System.Entity" PropertyID="DisplayName"/>

    </DiscoveryClass>

  </DiscoveryTypes>

  <DataSource ID="DS" TypeID="Windows!Microsoft.Windows.TimedScript.DiscoveryProvider">

    <IntervalSeconds>43255</IntervalSeconds>

    <SyncTime/>

    <ScriptName>HIS2010 WIP Discovery.vbs</ScriptName>

    <Arguments>$MPElement$ $Target/Id$ $Target/Host/Property[Type="Windows!Microsoft.Windows.Computer"]/PrincipalName$</Arguments>

    <ScriptBody><Script>

'--------------------------------------------------------------------------------------------------

' &lt;name&gt;HIS2010 WIP Discovery.vbs&lt;/name&gt;

' &lt;company&gt;Microsoft Corporation&lt;/company&gt;

' &lt;copyright&gt;Copyright (c) Microsoft Corporation 2010&lt;/copyright&gt;

' &lt;summary&gt;

'   Microsoft Host Integration Server 2010 WIP discovery script for use with SCOM 2007.

'	Provides discovery functions for Host Integration Server 2010 WIP. 

' &lt;/summary&gt;

'

' See Management Pack Guide for details on parameters and usage

'--------------------------------------------------------------------------------------------------



SetLocale("en-us")

Dim oAPI, oDiscoveryData, oInst

Set oAPI = CreateObject("MOM.ScriptAPI")



Dim oArgs

Set oArgs = WScript.Arguments

if oArgs.Count &lt; 3 Then

   Wscript.Quit -1

End If



Dim SourceID, ManagedEntityId, TargetComputer



SourceId = oArgs(0)

ManagedEntityId = oArgs(1)

TargetComputer = oArgs(2)



set oDiscoveryData = oAPI.CreateDiscoveryData(0, SourceId, ManagedEntityId)



Dim bDisableTN3Monitoring, bDisableTN5Monitoring, bDisablePrintMonitoring, bDisableHIPMonitoring, bDisableLU62ResyncMonitoring, bDisableIPResyncMonitoring

Dim bDisableSIMonitoring, bDisableMIMonitoring, bDisableDIMonitoring, bDisableWIPMonitoring



bDisableTN3Monitoring           = FALSE

bDisableTN5Monitoring           = FALSE

bDisablePrintMonitoring         = FALSE

bDisableHIPMonitoring           = FALSE

bDisableLU62ResyncMonitoring    = FALSE

bDisableIPResyncMonitoring      = FALSE

bDisableSIMonitoring            = FALSE

bDisableMIMonitoring            = FALSE

bDisableDIMonitoring            = FALSE

bDisableWIPMonitoring           = FALSE



GetRegParams()

WIPDiscovery()



call oAPI.Return(oDiscoveryData)



Sub GetRegParams()



    ' Performs all registry lookups required for service discovery.



    Const WMI_REG_HKLM 			= &amp;H80000002



    Const HIS_OPTOUT_KEYPATH        = "SOFTWARE\Microsoft\SNA Server\CurrentVersion\Monitoring\"

    Const HIS_TN3_OPTOUT_KEY        = "DisableTN3270Monitoring"

    Const HIS_TN5_OPTOUT_KEY        = "DisableTN5250Monitoring"

    Const HIS_PRINT_OPTOUT_KEY      = "DisablePrintMonitoring"

    Const HIS_HIP_OPTOUT_KEY        = "DisableHIPMonitoring"

    Const HIS_LU62RESYNC_OPTOUT_KEY = "DisableLU62ResyncMonitoring"

    Const HIS_IPRESYNC_OPTOUT_KEY   = "DisableIPResyncMonitoring"

    Const HIS_SI_OPTOUT_KEY         = "DisableSessionIntegratorMonitoring"

    Const HIS_DI_OPTOUT_KEY         = "DisableDataIntegrationMonitoring"

    Const HIS_MI_OPTOUT_KEY         = "DisableMessageIntegrationMonitoring"

    Const HIS_WIP_OPTOUT_KEY        = "DisableWIPMonitoring"



    Const HIS_SNA_CONFIG_KEYPATH            = "SOFTWARE\Microsoft\Host Integration Server\ConfigFramework\ConfiguredFeatures"

    Const HIS_SNA_SERVICE_KEY               = "SNA_SERVICE"

    Const HIS_SNA_APPLICATION_SUPPORT_KEY   = "SNA_APPLICATION_SUPPORT"



    Dim oRegProvider

    Dim intReturn

    Dim colValues, strValue

    Dim colTypes



    ' =============================================================

    ' Check for the possible set of monitoring opt-out keys, and for each that exists

    ' set the corresponding boolean variable to TRUE



    Set oRegProvider = GetObject("winmgmts:\\" &amp; TargetComputer &amp; "\root\default:StdRegProv")



    intReturn = oRegProvider.EnumValues(WMI_REG_HKLM, HIS_OPTOUT_KEYPATH, colValues, colTypes)



    If intReturn = 0 And Not (IsNull(colValues)) Then



        For Each strValue In colValues



            Select Case strValue



                Case HIS_TN3_OPTOUT_KEY

                    bDisableTN3Monitoring = True

                    

                Case HIS_TN5_OPTOUT_KEY

                    bDisableTN5Monitoring = True

                    

                Case HIS_PRINT_OPTOUT_KEY

                    bDisablePrintMonitoring = True

                    

                Case HIS_HIP_OPTOUT_KEY

                    bDisableHIPMonitoring = True

                    

                Case HIS_LU62RESYNC_OPTOUT_KEY

                    bDisableLU62ResyncMonitoring = True

                    

                Case HIS_IPRESYNC_OPTOUT_KEY

                    bDisableIPResyncMonitoring = True

                    

                Case HIS_SI_OPTOUT_KEY

                    bDisableSIMonitoring = True

                    

                Case HIS_MI_OPTOUT_KEY

                    bDisableMIMonitoring = True

                    

                Case HIS_DI_OPTOUT_KEY

                    bDisableDIMonitoring = True

                    

                Case HIS_WIP_OPTOUT_KEY

                    bDisableWIPMonitoring = True

                    

            End Select

        Next

    End If



End Sub 'GetRegParams





Sub WIPDiscovery()

	

    CONST HIS_WIP_FEATURE = "TRANSACTION_INTEGRATOR"

	

    Dim intWIP

    intWIP = 0

    

    If NOT bDisableWIPMonitoring Then

  

	  ' =============================================================

        ' Check for MSI feature installed



	    intWIP = FindFeature(HIS_WIP_FEATURE)

    		

	    if NOT intWIP = 0 then

          	set oInst = oDiscoveryData.CreateClassInstance("$MPElement[Name='Microsoft.HostIntegrationServer.2010.WIP']$")

	      call oInst.AddProperty("$MPElement[Name='Windows!Microsoft.Windows.Computer']/PrincipalName$", TargetComputer)

	      call oInst.AddProperty("$MPElement[Name='System!System.Entity']/DisplayName$", "WIP Application")

	      call oDiscoveryData.AddInstance(oInst)

	    end if



	End If

	

End Sub 'WIPDiscovery



Function FindFeature(strFeatureName)



	' Query MSI to determine if the specified HIS feature name is installed or advertised. 

	' Return 1 if true, 0 if false

	

    CONST HIS_2010_PRODUCT_CODE = "{2FAAF841-F52B-41DD-BE4C-3C249CAFF637}"

    CONST INSTALLSTATE_LOCAL  =  3

    

	dim installer, feature, features, state

	

	set installer = CreateObject("WindowsInstaller.Installer")			

	set features = installer.Features(HIS_2010_PRODUCT_CODE)

	

	for each feature in features

		if feature = strFeatureName then

			state = installer.FeatureState(HIS_2010_PRODUCT_CODE, feature)

			if state = INSTALLSTATE_LOCAL then

				FindFeature = 1

			else

				FindFeature = 0

			end if

			Exit Function

		end if

	next

	

	FindFeature = 0

	Exit Function



End function  'FindFeature

</Script></ScriptBody>

    <TimeoutSeconds>360</TimeoutSeconds>

  </DataSource>

</Discovery>