PerfDataWithNoReductionGet.SP.sql (Resource)

Element properties:

Source Code:

<Resource ID="PerfDataWithNoReductionGet.SP.sql" Accessibility="Internal" FileName="PerfDataWithNoReductionGet.SP.sql"/>

File Content: PerfDataWithNoReductionGet.SP.sql

IF NOT EXISTS (SELECT * FROM sysobjects WHERE type = 'P' AND name = 'Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet' AND UID = SCHEMA_ID('SDK'))


BEGIN


    EXECUTE ('CREATE PROCEDURE SDK.Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet AS RETURN 1')


END


GO





ALTER PROCEDURE [SDK].[Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet]


     @StartTime datetime


    ,@EndTime datetime


    ,@ManagedEntityRowId int


    ,@PerfRuleInstanceRowId int


    ,@AggregationType int


    ,@RowCount int OUTPUT


AS


BEGIN


    SET NOCOUNT ON





    DECLARE


         @ErrorInd         bit


        ,@ErrorMessage     nvarchar(max)


        ,@ErrorNumber      int


        ,@ErrorSeverity    int


        ,@ErrorState       int


        ,@ErrorLine        int


        ,@ErrorProcedure   nvarchar(256)


        ,@ErrorMessageText nvarchar(max)





    SET @ErrorInd = 0





/* ------------------------------ */





    DECLARE @Error int


    DECLARE @ExecError int





    BEGIN TRY





        IF @ManagedEntityRowId IS NULL


        BEGIN


            RAISERROR (777971002, 16, 1


                ,0


                ,0


                ,0


                ,N'SDK.Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet'


                ,0


                ,N'Non existent managed entity'


            )


        END








/* ------------------------------ */








        DECLARE @SelectStatement nvarchar(max)


        DECLARE @WhereStatement nvarchar(max)


        DECLARE @TimeStatement nvarchar(max)


        DECLARE @SqlStatement nvarchar(max)


        DECLARE @ViewName nvarchar(max)


        DECLARE @ColumnName nvarchar(max)





        IF @AggregationType = 0


        BEGIN


            SET @ViewName = 'Perf.vPerfRaw'


            SET @ColumnName = 'vPerf.SampleValue'


            SET @TimeStatement = '


                AND vPerf.DateTime >= @StartTime


                AND vPerf.DateTime <= @EndTime


                '


        END


        ELSE IF @AggregationType = 20


        BEGIN


            SET @ViewName = 'Perf.vPerfHourly'


            SET @ColumnName = 'vPerf.AverageValue'


            SET @TimeStatement = '


                AND (vPerf.DateTime >= DATEADD(hh, DATEPART(hh, @StartTime), convert(varchar(8), @StartTime, 112)))


                AND (vPerf.DateTime < DATEADD(hh, DATEPART(hh, @EndTime), convert(varchar(8), @EndTime, 112)))


                '


        END


        ELSE IF @AggregationType = 30


        BEGIN


            SET @ViewName = 'Perf.vPerfDaily'


            SET @ColumnName = 'vPerf.AverageValue'


            SET @TimeStatement = '


                AND (vPerf.DateTime >= DATEADD(hh, DATEPART(hh, @StartTime), convert(varchar(8), @StartTime, 112)))


                AND (vPerf.DateTime < DATEADD(hh, DATEPART(hh, @EndTime), convert(varchar(8), @EndTime, 112)))


                '


        END


        ELSE


        BEGIN


            RAISERROR (777971002, 16, 1


                ,0


                ,0


                ,0


                ,N'SDK.Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet'


                ,0


                ,N'Invalid AggregationType - only 0, 20, and 30 are supported'


            )


        END








        SET @SelectStatement = '


            SELECT DateTime,' + @ColumnName + ' FROM ' + @ViewName + ' AS vPerf


                '





        SET @WhereStatement = '


            WHERE vPerf.ManagedEntityRowId = @ManagedEntityRowId


                AND vPerf.PerformanceRuleInstanceRowId = ' + convert(varchar(10), @PerfRuleInstanceRowId)


    


        SET @SqlStatement = @SelectStatement + @WhereStatement + @TimeStatement + 'ORDER BY vPerf.DateTime ASC'





        EXEC sp_executesql @SqlStatement,


            @params = N'


                @ManagedEntityRowId int,


                @StartTime datetime,


                @EndTime datetime',


            @ManagedEntityRowId = @ManagedEntityRowId,


            @StartTime = @StartTime,


            @EndTime = @EndTime


         


         SELECT @RowCount = @@ROWCOUNT


            


    END TRY


    BEGIN CATCH


        IF (@@TRANCOUNT > 0)


            ROLLBACK TRAN





        SELECT


             @ErrorNumber = ERROR_NUMBER()


            ,@ErrorSeverity = ERROR_SEVERITY()


            ,@ErrorState = ERROR_STATE()


            ,@ErrorLine = ERROR_LINE()


            ,@ErrorProcedure = ISNULL(ERROR_PROCEDURE(), '-')


            ,@ErrorMessageText = ERROR_MESSAGE()





        SET @ErrorInd = 1


    END CATCH





    -- report error if any


    IF (@ErrorInd = 1)


    BEGIN


        DECLARE @AdjustedErrorSeverity int





        SET @AdjustedErrorSeverity = CASE


                                         WHEN @ErrorSeverity > 18 THEN 18


                                         ELSE @ErrorSeverity


        END





        RAISERROR (777971002, @AdjustedErrorSeverity, 1


            ,@ErrorNumber


            ,@ErrorSeverity


            ,@ErrorState


            ,@ErrorProcedure


            ,@ErrorLine


            ,@ErrorMessageText


        )


    END


END


GO





GRANT EXECUTE ON [SDK].[Microsoft_SystemCenter_Visualization_Library_PerfDataWithNoReductionGet] TO OpsMgrReader


GO